自動化
PR

Power Automate Desktopのループの使い方|Loop・For each・ループ条件の違いと途中で抜ける方法

sanane
記事内に商品プロモーションを含む場合があります

Power Automate Desktop(PAD)で同じ処理をくり返したいとき、ループのアクションはLoop・For each・ループ条件の3種類があります。どれを使えばいいのか、Excelの表を空白の行まで処理するにはどうするのか、迷いやすいところです。

この記事では、Windows 11で実際にフローを作って、3つのループの違い、ループを抜ける/次のループの動き、ループ条件を複数にする書き方、無限ループの止め方を確かめた結果をまとめます。

こんな人にオススメ
  • Power Automate DesktopのLoop と For each の違いが分からない
  • Excelの表を空白の行まで1行ずつ処理したい
  • ループを途中で抜けたい・ループ条件を複数にしたい
あわせて読みたい
Power Automateとは?できること・使い方・始め方を実例53本で解説
Power Automateとは?できること・使い方・始め方を実例53本で解説

先に結論|回数ならLoop、表やリストならFor each、条件ならループ条件

アクション何回まわるか使う変数向いている場面
Loop開始値〜終了まで、増分ずつLoopIndex(今の番号)回数が決まっている
For eachリスト・表の件数だけCurrentItem(今の1件)Excelの表・ファイルの一覧を1件ずつ
ループ条件条件が成り立つあいだ(自分で用意)「〜になるまで」くり返す

途中で止めたいときはループを抜ける、その回だけ飛ばしたいときは次のループを使います。

確認した環境:Windows 11 Home 26H2、Power Automate Desktop 11.2610.155.0、個人のMicrosoftアカウント。

アクション ペインのループの中身。For each、Loop、ループを抜ける、ループ条件、次のループ

Loop:決まった回数くり返す

Loopは、開始値から終了まで、増分ずつ数を増やしながらくり返します。今の数は変数 LoopIndex に入ります。

Loop の設定。開始値1、終了5、増分1、生成された変数 LoopIndex

次の2つのLoopで、LoopIndexを文字につなげて確かめました。

SET Text TO $''''''
LOOP LoopIndex FROM 1 TO 5 STEP 1
    SET Text TO $'''%Text%%LoopIndex% '''
END
SET Text2 TO $''''''
LOOP LoopIndex2 FROM 10 TO 1 STEP -3
    SET Text2 TO $'''%Text2%%LoopIndex2% '''
END
Display.ShowMessageDialog.ShowMessage Title: $'''Loop の結果''' Message: $'''1 から 5 まで増分 1:%Text%
10 から 1 まで増分 -3:%Text2%''' Icon: Display.Icon.None Buttons: Display.Buttons.OK DefaultButton: Display.DefaultButton.Button1 IsTopMost: True ButtonPressed=> ButtonPressed

結果は、1から5まで増分1で 1 2 3 4 5、10から1まで増分-3で 10 7 4 1 でした。増分をマイナスにすれば逆順にまわせます。終了の数(1)にちょうど当たらない場合も、超える手前で止まりました。

変数欄に Text 1 2 3 4 5、Text2 10 7 4 1 と表示。ループ後の LoopIndex は 6、LoopIndex2 は -2

ループのあとの LoopIndex は「終了」を超えた値になる

ループのあとでLoopIndexを使うと、最後に処理した値ではありませんでした。ループの後ろにメッセージを置いて確かめると、LoopIndex=6(最後に処理したのは5)、LoopIndex2=-2(最後に処理したのは1)と、増分をもう1回足した値になっていました。

ループ後のメッセージに ループ後の LoopIndex=6/LoopIndex2=-2 と表示。実行中の変数欄は LoopIndex 5、LoopIndex2 1 のまま

実行中の変数欄は LoopIndex 5 のまま表示されていて、フローが終わってから6に変わりました。変数欄の表示だけを見ると「最後の値が残る」と勘違いしやすいので、ループのあとで「何回まわったか」を使うときは注意してください。

For each:Excelの表を1行ずつ処理する

For eachは、リストや表(データテーブル)を1件ずつ取り出してくり返します。取り出した1件は CurrentItem に入ります。

試したExcelは、商品名・数量・単価の表で、途中に空白の行を1行入れたものです。「Excel ワークシートから読み取る」でシート全体を読み込むと、空白の行も1行として入って「7 行, 3 列」になりました。行の番号は0から数えます。

ExcelData の中身。0 りんご 3 120、1 みかん 5 80、2 ぶどう 2 400、3 もも 4 250、4 メロン 1 1200、5 空白、6 いちご 6 300

Excelの読み込み方(範囲の最初の行に列名が含まれています をオンにする など)はPower Automate DesktopでExcelを操作する方法で詳しく解説しています。

For eachの中では、%CurrentItem['商品名']%(列の名前)や %CurrentItem[1]%(列の番号・0から)で値を取り出せました。

Excelの起動、ワークシートから読み取る、For each CurrentItem in ExcelData の中で変数を大きくするとLinesに追加、Excelを閉じる。RowNo は 7

For eachには「何行目か」の変数がない

For eachには、LoopのLoopIndexのような「今何件目か」を表す変数がありません。何行目かを使いたいときは、ループの前に変数(ここでは RowNo)を0にしておき、ループの中で「変数を大きくする」で1ずつ増やします。

結果は次のとおりで、空白の行(6)も処理されたことが分かります。

Lines の中身。1:りんご ×3、2:みかん ×5、3:ぶどう ×2、4:もも ×4、5:メロン ×1、6:(空白)×、7:いちご ×6
Excel.LaunchExcel.LaunchAndOpenUnderExistingProcess Path: $'''C:\Users\Public\PADテスト\商品リスト.xlsx''' Visible: True ReadOnly: False UseMachineLocale: False Instance=> ExcelInstance
Excel.ReadFromExcel.ReadAllCells Instance: ExcelInstance GetCellContentsMode: Excel.GetCellContentsMode.TypedValues FirstLineIsHeader: True RangeValue=> ExcelData
SET Lines TO $''''''
SET RowNo TO 0
LOOP FOREACH CurrentItem IN ExcelData
    Variables.IncreaseVariable Value: RowNo IncrementValue: 1
    SET Lines TO $'''%Lines%%RowNo%:%CurrentItem['商品名']% ×%CurrentItem[1]%
'''
END
Excel.CloseExcel.Close Instance: ExcelInstance

ループを抜ける/次のループ:空白の行で止める・飛ばす

For eachの先頭にIf(商品名が空である)を置き、中にループを抜けるを入れると、空白の行でループが終わりました。RowNoは5で、空白の下の「いちご」は処理されません。「空白の行まで処理する」ならこの形です。

For each の中に If CurrentItem['商品名'] 空である then ループを抜ける。RowNo は 5

同じ場所を次のループにすると、空白の行だけ飛ばして続きが処理されました。RowNoは6で、最後に「いちご」も入っています。

If の中を次のループにしたフロー。RowNo は 6
Lines の中身。1:りんご 〜 5:メロン、6:いちご ×6
ループを抜ける次のループ
動きループそのものを終えるその回の残りを飛ばして、次の回へ
空白の行で使うと空白より下は処理しない空白の行だけ飛ばす
スクリプト形式EXIT LOOPNEXT LOOP

ループ条件:条件が成り立つあいだくり返す

ループ条件は、最初のオペランド・演算子・2 番目のオペランドで決めた条件が成り立つあいだ、くり返します。演算子は次の6つだけで、Ifにある「空である」「次を含む」などはありません。

ループ条件の演算子。と等しい、と等しくない、より大きい、以上である、より小さい、以下である

Index(0から始めて1ずつ増やす)が ExcelData.RowsCount(行数)より小さいあいだ、という条件にすると、0〜6の7回まわりました。

ループ条件 While (Index) < (ExcelData.RowsCount) の中で Lines に追加し Index を大きくする。Index は 7

ループ条件を複数にする(AND でつなぐ)

ループ条件の画面には、条件を1つしか書けません。2つ以上の条件にしたいときは、最初のオペランドに式を書いて、2 番目のオペランドの %True% と比べます。

ループ条件。最初のオペランドに %Index < ExcelData.RowsCount AND ExcelData[Index]['商品名'] <> ''%、演算子 と等しい、2 番目のオペランド %True%

「行数より小さい」かつ「商品名が空ではない」という条件で、空白の行の手前(Index=5)で止まりました。

ループ条件 While (Index < ExcelData.RowsCount And ExcelData[Index]['商品名'] <> '') =(True)。Index は 5
Excel.LaunchExcel.LaunchAndOpenUnderExistingProcess Path: $'''C:\\Users\\Public\\PADテスト\\商品リスト.xlsx''' Visible: True ReadOnly: False UseMachineLocale: False Instance=> ExcelInstance

Excel.ReadFromExcel.ReadAllCells Instance: ExcelInstance GetCellContentsMode: Excel.GetCellContentsMode.TypedValues FirstLineIsHeader: True RangeValue=> ExcelData

SET Index TO 0

SET Lines TO $''''''

LOOP WHILE (Index < ExcelData.RowsCount AND ExcelData[Index]['商品名'] <> '') = (True)

    SET Lines TO $'''%Lines%%Index%:%ExcelData[Index]['商品名']%

'''

    Variables.IncreaseVariable Value: Index IncrementValue: 1

END

Excel.CloseExcel.Close Instance: ExcelInstance

「または」にしたいときは AND の代わりに OR を使います。

無限ループになったときの止め方

条件がずっと成り立つ(例:Count が0以上のあいだ、Countを増やし続ける)と、ループは終わりません。

ループ条件 While (Count) >= (0) が実行中のまま。上に一時停止と停止のボタン

デザイナーから実行しているときは、上の[停止]で止まりました。止めたあとのステータスは「準備完了」で、エラーにはなりません。

コンソールから実行したフローを止めるキーを決めておきたいときは、コンソールの[設定]→「フロー実行コントロール」で、フローの一時停止/再開・フローを停止するのキーボード ショートカットを設定できます(既定は未設定)。

設定のフロー実行コントロール。キーボード ショートカットを設定して、実行中のフローを一時停止/再開または停止します。フローの一時停止/再開、フローを停止するの入力欄

この記事では、設定画面の確認だけをしていて、ショートカットを実際に設定して止めるところまでは試していません。

よくある質問

Q
LoopとFor eachの違いは何ですか?

Loopは開始値〜終了まで決まった回数まわり、今の数がLoopIndexに入ります。For eachはリストや表の件数だけまわり、今の1件がCurrentItemに入ります。Excelの表を1行ずつ処理するならFor eachが向いています。

Q
Excelの表を空白の行まで処理するには?

For eachの先頭にIf(列の値が空である)を置き、その中に「ループを抜ける」を入れます。空白の行でループが終わりました。空白の行だけ飛ばしたいなら「次のループ」です。

Q
For eachで今何行目かを知るには?

For eachには件数の変数がありません。ループの前に変数を0にして、ループの中で「変数を大きくする」で1ずつ増やすと、行番号として使えます。

Q
ループ条件を複数にできますか?

画面には条件を1つしか書けませんが、最初のオペランドに %条件1 AND 条件2% のような式を書き、2 番目のオペランドを %True% にすると、2つの条件でまわせました。

Q
無限ループを止めるには?

デザイナーから実行中なら上の[停止]で止まります。コンソールから実行するフローは、設定の「フロー実行コントロール」で停止のショートカットを決めておけます。

まとめ

  • 回数が決まっているならLoop(LoopIndex)、増分をマイナスにすると逆順
  • Excelの表やリストはFor each(CurrentItem)。空白の行も1行として入る
  • 空白で止めるならループを抜ける、飛ばすなら次のループ
  • ループ条件は1つしか書けないが、式とTrueを比べれば複数条件にできる
  • 無限ループはデザイナーの[停止]で止まる

クラウド版のPower Automateで、くり返しの「それぞれに適用する」を使う方法はこちらです。

あわせて読みたい
Power Automateの「それぞれに適用する」の使い方|並列化で高速化・入れ子・途中で抜ける方法
Power Automateの「それぞれに適用する」の使い方|並列化で高速化・入れ子・途中で抜ける方法

フォルダーの中のファイルを1つずつ処理する例として、ファイル名の一括変更も紹介しています。

あわせて読みたい
Power Automate Desktopでファイル名を一括変更する方法|連番・文字の追加と順番がずれるときの対処
Power Automate Desktopでファイル名を一括変更する方法|連番・文字の追加と順番がずれるときの対処
記事URLをコピーしました